subroutine mpical(sst,rmpi,ibasin)
c     This routine calculates the maximum potential intensity (kt)
c     from the sst (C) using empirical relationships.
c
c     ibasin=1 for Atlantic
c     ibasin=2 for East/Central Pacific
c     ibasin=3 for West Pacific
c     ibasin=4 North Indian Ocean (WP formula used)
c     ibasin=5 for Southern Hemisphere (AL formula used)
c      
c     Check for illegal sst values 
      if (sst .gt. 35.0 .or. sst .lt. 0.0) then
         rmpi=999.9
         return
      endif
c
      if (ibasin .eq. 1 .or. ibasin .eq. 5) then
c        Atlantic function (speed adjusted, DeMaria and Kaplan 1994)
         vcold = 34.2
         vadd  = 55.8
         a     = 0.1813
         tmax  = 30.00
c
         rmpi = vcold + vadd*exp(-a*(tmax-sst))
         rmpi = rmpi*1.944
      elseif (ibasin .eq. 2) then
c        East Pacific function (speed adjusted, Whitney and Hopgood 1995)
         a = -79.2
         b = 5.362
         c = 4.7
C
         tmin = 20.0
         sstt = sst
         if (sstt .lt. tmin) sstt=tmin
C
         rmpi = a + b*sstt + c
         rmpi = rmpi*1.944
      elseif (ibasin .eq. 3 .or. ibasin .eq. 4) then
C        West Pacific function
         vcold = 19.7
         vadd  = 88.0
         a     = .1909
         tmax  = 30.00
C
         rmpi  = vcold + vadd*exp(-a*(tmax-sst))
         rmpi  = rmpi*1.944
      else
         rmpi = 999.9
         return
      endif
C
      if (rmpi .gt. 165.0) rmpi=165.0
c
      return
      end