SUBROUTINE LTGSUM(KFILDO,FLT1,FLT3X3,NX,NY)
C
C        MAY      2005   CHARBA  MDL   MOS-2000
C
C        PURPOSE
C           OBTAINS THE NUMBER OF LIGHTNING STRIKES IN 3X3 10-KM GRID
C	    WINDOWS.
C
C        DATA SET USE
C           KFILDO - UNIT NUMBER FOR OUTPUT (PRINT) FILE.  (OUTPUT)
C
C        VARIABLES
C              KFILDO = UNIT NUMBER FOR OUTPUT (PRINT) FILE.  (INPUT)
C		   NX = MAX NUMBER OF GRIDPOINTS IN X-DIRECTION.  
C			(INPUT)
C	           NY = MAX NUMBER OF GRIDPOINTS IN Y-DIRECTION.
C			(INPUT)
C           FLT1(I,J) = NUMBER OF LIGHTNING FLASHES IN 10-KM GRIDBOX
C			(I=1,NX,J=1,NY).  (INPUT)
C         FLT3X3(I,J) = NUMBER OF LIGHTNING FLASHES IN 3X3 WINDOW OF
C		        10-KM GRIDBOXES (I=1,NX,J=1,NY).  (OUTPUT)
C
C        NON SYSTEM ROUTINES CALLED
C            NONE.
C      
      DIMENSION FLT1(NX,NY),FLT3X3(NX,NY)
C
      DO 200 J=1,NY
      DO 200 I=1,NX
        FLT3X3(I,J)=0.0
        ICOUNT=0
C
C          GET THE BEGINNING AND ENDING INDEX OF
C          SURROUNDING GRIDPOINTS
C
        IBX=MAX(1,I-1)
        IBY=MAX(1,J-1)
        IEX=MIN(NX,I+1)
        IEY=MIN(NY,J+1)
C
C          CALCULATE STRIKE COUNT IN 3X3 WINDOWS. 
C
        DO 150 JY=IBY,IEY
        DO 150 IX=IBX,IEX
          TMP=FLT1(IX,JY)
          IF(TMP.NE.9999.)THEN
             FLT3X3(I,J)=FLT3X3(I,J)+TMP
             ICOUNT=ICOUNT+1
          ENDIF
 150    CONTINUE
C
        IF(ICOUNT.EQ.0)THEN
          FLT3X3(I,J)=9999.
        ENDIF
C
 200  CONTINUE
C
      RETURN
      END