SUBROUTINE POSTVA(KFILDO,P,NX,NY,SEALND,NXE,NYE,
     1                   TLO,SETLO,THI,SETHI,IER)
C
C        MAY         2019   GLAHN   MDL   MOS-2000
C
C        PURPOSE
C            TO POSTPROCESS A VISIBILITY ANALYSIS FOR ALASKA.
C            LOW AND HIGH VALUES ARE SET ACCORDING TO THRESHOLDS.
C            ONLY LAND VALUES EXCLUSIVE OF SIBERIA ARE MODIFIED.
C            NO OTHER PROCESSING IS DONE.
C
C            THE MAJOR PURPOSE IS TO SET VALUES OF VISIBILITY
C            GREATER THAN THI TO SETHI.  IT TAKES THE PLACE OF
C            POSTPM IN THE CONUS (WHICH WILL LIKELY HAVE TO BE 
C            MODIFIED IN THE NEXT ITERATION).
C
C            "VA" IN THE NAME STANDS FOR VISIBILITY ALASKA.
C   
C        DATA SET USE
C            KFILDO    - UNIT NUMBER OF OUTPUT (PRINT) FILE.  (OUTPUT)
C
C        VARIABLES
C              KFILDO = UNIT NUMBER OF OUTPUT (PRINT) FILE.  (INPUT)
C            P(IX,JY) = THE DATA TO PROCESS (IX=1,NX) (JY=1,NY).
C                       (INPUT-OUTPUT)
C                  NX = THE FIRST DIMENSION OF P( , ).  (INPUT)
C                  NY = THE SECOND DIMENSION OF P( , ).  (INPUT)
C       SEALND(IX,JY) = THE LAND/WATER MASK (IX=1,NXE) (JY=1,NYE).
C                       (INPUT)
C                 NXE = THE FIRST DIMENSION OF SEALND( , ). (INPUT)
C                 NYE = THE SECOND DIMENSION OF SEALND( ,).  (INPUT)
C                 TLO = LOW THRESHOLD.  WHEN A GRIDPOINT IS LT TLO,
C                       IT IS SET TO SETLO.  (INPUT)
C               SETLO = SEE TLO.  (INPUT)
C                 THI = HIGH THRESHOLD.  WHEN A GRIDPOINT IS GT THI,
C                       IT IS SET TO SETHI.  (INPUT)
C               SETHI = SEE THI.  (INPUT)
C                 IER = ERROR RETURN.
C                       0 = GOOD RETURN.
C                       (OUTPUT)
C        1         2         3         4         5         6         7 X
C 
C        NONSYSTEM SUBROUTINES USED 
C            NONE
C
      DIMENSION P(NX,NY),SEALND(NXE,NYE)
C
      CALL TIMPR(KFILDO,KFILDO,'START POSTVA        ')
      IER=0
C
C        CHECK DIMENSIONS OF P( ,) AND SEALND( ,) FOR SAFETY.
  
      IF(NX.NE.NXE.OR.NY.NE.NYE)THEN
         WRITE(KFILDO,105)
 105     FORMAT(' DIMENSIONS OF P( , ) AND SEALND( , ) ARE NOT THE',
     1          ' SAME IN POSTVA.  STOP AT 105.')
         STOP 105
      ENDIF
C
      DO 200 JY=1,NY
      DO 199 IX=1,NX
C
      IF(SEALND(IX,JY).GT.8.9)THEN
C           THIS IS A LAND GRIDPOINT.
C
         IF(IX.GT.610.OR.JY.LT.756)THEN
C              THIS CHECK EXCLUDES SIBERIA ON THE NBM 3-KM GRID.
C
            IF(NINT(P(IX,JY)).NE.9999)THEN
C                 A MISSING VALUE IS NOT CHANGED.
C
               IF(P(IX,JY).LT.TLO)THEN
                  P(IX,JY)=SETLO
C                    THIS IS TO ELIMINATE NEGATIVES WHEN TLO = 0.
               ELSEIF(P(IX,JY).GT.THI)THEN
                  P(IX,JY)=SETHI
C                    THIS IS TO CREATE A FLAT AREA OF 10'S (UNLIMITED
C                    VISIBILITY) WHEN TLO ~ 9.1 AND SETLO = 10.
               ENDIF
C
            ENDIF
C
         ENDIF
C
      ENDIF
C
 199  CONTINUE
 200  CONTINUE
C
      CALL TIMPR(KFILDO,KFILDO,'END   POSTVA        ')
C
 150  RETURN
      END