SUBROUTINE GLFFST(KFILDO,P,NX,NY,MESH,SEALND,NXE,NYE,MESHE,
     1                  GUESS,IER)
C
C        DECEMBER  2019   GLAHN   TDL   MOS-2000
C        FEBRUARY  2020   GLAHN   ADDED JGULF TO COMMON BLOCK 
C        FEBRUARY  2020   GLAHN   CHANGED JGUFL = 0 TO = 1
C        
C        PURPOSE
C            TO PROVIDE A FIRST GUESS FOR THE NORTHWESTERN GULF OF
C            MEXICO.  THIS AREA HAS OIL PLATFORMS AND CAN BE ANALYZED.
C            IF THE FIRST GUESS IS A MODEL, AS THE REST OF THE WATER
C            MAY BE, THE ANALYSIS IS NOT GOOD.
C      
C            NOTE THAT THE NORTHWESTERN GULF IS IN TERMS OF GRIDPOINT
C            VALUES AT 2.5-KM.  THIS WILL HAVE TO BE ADJUSTED FOR OTHER
C            MESH LENGTHS OR AREAS.  OTHER ROUTINES MAY HAVE TO BE
C            COORDINATED.  THE COMMON BLOCK COMMUNICATES WITH SKYLVS
C            AND SKYVHS.
C
C        DATA SET USE
C            KFILDO   - UNIT NUMBER FOR OUTPUT (PRINT) FILE.  (OUTPUT)
C
C        VARIABLES
C              KFILDO = UNIT NUMBER FOR OUTPUT (PRINT) FILE.  (INPUT)
C            P(IX,JY) = THE FIRST GUESS (IX=1,NX) (JY=1,NY).  
C                       (INPUT/OUTPUT)
C               NX,NY = SIZE OF P( , ).  (INPUT)
C                MESH = MESH LENGTH OF P( , ) AND SEALND( , ).  (INPUT)
C       SEALND(IX,JY) = THE LAND/SEA MASK AT NOMINAL MESHLENGTH MESHE
C                       (IX=1,NXE) (JY=1,NYE).
C                       0 = OCEAN WATER GRIDPOINTS;
C                       3 = INLAND WATER GRIDPOINTS.
C                       9 = LAND GRIDPOINTS.
C                       (INPUT)
C             NXE,JYE = SIZE OF SEALND( , ).  (INPUT)
C               MESHE = THE NOMINAL MESH LENGTH OF SEALND( ).  (INPUT)
C               GUESS = THE VALUE THE NORTHWESTERN GULF IS TO BE SET TO.
C                       (INPUT)
C                 IER = 0 = GOOD RETURN
C                       777 = GULF COULD NOT BE SET AS DESIRED.
C                       (OUTPUT)
C
C        COMMON BLOCK GULF
C               JGULF = 1 INCICATES THE FULF OF MEXICO IS TO BE 
C                         SMOOTHED AND THE OTHER OACEAN IS NOT.
C                       0 INOPERATIVE; DOES NOT AFFECT SMOOTHING
C              IXEAST = EASTERN IX OF AREA FS SET TO GUESS.
C              IXWEST = WESTERN IX OF AREA FS SET TO GUESS.
C              JYSRTH = SOUTHERN JY OF AREA FS SET TO GUESS.
C              JYNRTH = NORTHERN JY OF AREA FS SET TO GUESS.
C        1         2         3         4         5         6         7 X
C
C        NONSYSTEM SUBROUTINES CALLED
C            NONE
C
      COMMON/GULF/JGULF,IXEAST,IXWEST,JYSRTH,JYNRTH
C        THIS COMMON BLOCK IS USED FOR EASY COMMMUNICATION WITH SKYLVS
C        SKYLHS, SPOTRM, BCD5,AND BOGUSG
C
      DIMENSION P(NX,NY)
      DIMENSION SEALND(NX,NY)
C
      IER=0
      JGULF=1
C        JGULF = 1 MEANS GULF OF MEXICO IS TREATED DIFFERENTLY.
C        THIS IS NEEDED IN BOGUSG SO THAT GULF GRIDPONTS WON'T BE
C         SET TO ZERO.
      IXEAST=1825
C        KECP IS AT IX=1638.
      IXWEST=1167
C        KBKS IS AT IX=1167.
      JYSRTH=110
C        KBRO IS AT JY=145
      JYNRTH=384
C        KHBG IS AT JY=384
C
C
      WRITE(KFILDO,98)JGULF,IXEAST,IXWEST,JYSRTH,JYNRTH
 98   FORMAT(/' IN GLFFST--JGULF,IXEAST,IXWEST,JYSRTH,JYNRTH',5I6)
C
      IF(NX.EQ.NXE.AND.NY.EQ.NYE.AND.MESH.EQ.3.AND.MESH.EQ.MESHE)THEN
C        THE DIMENSION OF P( , ) AND SEALND( , ) ARE THE SAME AND
C        MESH = 3.  PROCEED.
C
         DO 120 JY=JYSRTH,JYNRTH
         DO 119 IX=IXWEST,IXEAST
C      
         IF(SEALND(IX,JY).EQ.0)THEN
            P(IX,JY)=GUESS
         ENDIF
C     
 119     CONTINUE
 120     CONTINUE
C
         WRITE(KFILDO,125)
 125     FORMAT(/' NORTHWESTERN GULF OF MEXICO SET TO GUESS.')
C
      ELSE
         WRITE(KFILDO,130)NX,NY,NXE,NYE,MESH
 130     FORMAT(/' SETTING NORTHWESTERN GULF OF MEXICO TO GUESS',
     1            ' FAILED.  NX, NY, NXE, NYE, MESH =',5I8) 
         IER=777
      ENDIF
C
      RETURN
      END