SUBROUTINE UA_PRS3  ( ppp, pres, iret )
C************************************************************************
C* UA_PRS3                                                              *
C*                                                                      *
C* This subroutine decodes pressure from a string of the form PPP.	*
C* If the input string PPP contains a non-numeric character, then	*
C* IRET is set to -1, and RMISSD is returned as the pressure.		*
C*									*
C* UA_PRS3  ( PPP, PRES, IRET )						*
C*                                                                      *
C* Input parameters:                                                    *
C*      PPP		CHAR*3		Encoded pressure		*
C*                                                                      *
C* Output parameters:                                                   *
C*      PRES		REAL		Pressure			*
C*	IRET		INTEGER		Return code:			*
C*					  0 = normal return		*
C*					 -1 = input string contained a	*
C*					      non-numeric character	*
C**                                                                     *
C* Log:									*
C* J. Ator/NCEP		03/96						*
C* J. Ator/NCEP		12/97	New interface format, style changes	*
C* J. Ator/NCEP		03/98	Set PRES=RMISSD for PPP="000" in CC, DD	*
C* J. Ator/NCEP		10/99	Clean up function declarations		*
C************************************************************************
	INCLUDE		'GEMPRM.PRM'
	INCLUDE		'uacmn.cmn'
C*
	CHARACTER	ppp*3
C------------------------------------------------------------------------
	iret = -1
	pres = RMISSD
C
	CALL ST_INTG  ( ppp, ipres, ier )
	IF  ( ier .eq. 0 )  THEN
	    IF  ( ( prttyp .eq. CC ) .or. ( prttyp .eq. DD ) )  THEN
		IF  ( ipres .ne. 0 )  THEN
		    pres = FLOAT ( ipres ) / 10.
		END IF
	    ELSE
		pres = FLOAT ( ipres )
		IF  ( pres .lt. 100. )  THEN
		    pres = pres + 1000.
		END IF
	    END IF
	    iret = 0
	END IF
C*
	RETURN
	END