SUBROUTINE SP_DCOD  ( cldt, rshpfl, bufrtn, nhours, iret )
C************************************************************************
C* SP_DCOD								*
C*									*
C* This routine decodes bulletins containing WMO-migrated ship BUFR	*
C* messages into NCEP BUFR format. 					*
C*									*
C* SP_DCOD ( CLDT, RSHPFL, BUFRTN, NHOURS, IRET )			*
C*									*
C* Input parameters:							*
C*	CLDT		CHAR*		Date-time from command line	*
C*	RSHPFL		CHAR*		List of WMO bulletins which	*
C*					contain restricted ship data	*
C*	BUFRTN		CHAR*		NCEP BUFR tables file		*
C*	NHOURS		INTEGER		Max # of hours before run time	*
C*					for creating NCEP BUFR output	*
C*									*
C* Output parameters:							*
C*	IRET		INTEGER		Return code:			*
C*					  0 = normal return		*
C*									*
C**									*
C* Log:									*
C* J. Ator/NCEP		03/15						*
C* M. Weiss/IMSG        11/19  Decode and store WIGOS IDs               *
C* J. Ator/NCEP         06/21  Process data from 3-08-018 sequence      *
C************************************************************************
	INCLUDE		'GEMPRM.PRM'
	INCLUDE		'BRIDGE.PRM'
C*
	CHARACTER*(*)	cldt, rshpfl, bufrtn
C*
C*	Maximum number of restricted ship bulletin headers.
C*
	PARAMETER	( MXRSHPB = 200 )
C*
C*	Maximum number of descriptors within Section 3 of a
C*	WMO SHIP BUFR message.
C*
	PARAMETER	( MXDSC = 50 )
C*
	PARAMETER	( MXMN = 50 )
C*
	CHARACTER	bull*(DCMXBF), cbull*(DCMXBF), bfstyp*8,
     +			seqnum*8, buhd*8, cborg*8, bulldt*8, bbb*8,
     +			rundt*12, sysdt*12, subtyp*8, logmsg*200,
     +			cdesc( MXDSC )*6, crshpb ( MXRSHPB )*11,
     +			cbb*11, smid*9, bufrdn*(DCMXLN),
     +                  bufrbn*(DCMXLN), wgoslid*16, tagpr*10
C*
	INTEGER		irundt ( 5 ), irptdt ( 5 ), 
     +			ibull ( DCMXBF / 4 )
C*
	LOGICAL		bullok, msgok, gotwigos, got818
C*
	REAL*8		r8in ( MXMN ), r8ot ( MXMN ), PKFTBV,
     +                  r8gust ( 3, 255 ), r8bfms, GETBMISS
C*
	EQUIVALENCE	( cbull (1:4), ibull (1) )
C*
	INCLUDE		'ERMISS.FNC'
C*-----------------------------------------------------------------------
	iret = 0
C
C*	Get the BUFR tables directory from the tables file.  This
C*	directory will be passed to subroutine MTINFO as the location
C*	in which to search for any needed master table files.
C
	CALL FL_PATH ( bufrtn, bufrdn, bufrbn, ierpth )
C
C*	Open, read and close the file of restricted bulletin headers.
C
	CALL FL_TBOP  ( rshpfl, 'rshp', irshpfl, iertop )
	IF ( iertop .ne. 0 ) THEN
	    CALL DC_WLOG  ( 0, 'FL', iertop, rshpfl, ierr )
	    RETURN     
	END IF
	iostat = 0
	nrshpb = 0
	DO WHILE  ( ( nrshpb .lt. MXRSHPB ) .and. ( iostat .eq. 0 ) )
	    READ  ( irshpfl, FMT = '(A)', IOSTAT = iostat )
     +		crshpb ( nrshpb + 1 )
	    IF  ( iostat .eq. 0 )  THEN
		nrshpb = nrshpb + 1
	    END IF
	END DO
	CALL FL_CLOS  ( irshpfl, iercls )
C
C*	Open the tables file for the NCEP BUFR (i.e. output) stream.
C
	CALL FL_SOPN ( bufrtn, iubftn, ierspn )
	IF ( ierspn .ne. 0 ) THEN
	  CALL DC_WLOG ( 0, 'FL', ierspn, bufrtn, ierwlg )
	  RETURN
	END IF
C
C*	Open the BUFR messages file.
C
	CALL FL_GLUN ( iubfma, iergln )
	IF ( iergln .ne. 0 ) THEN
	  CALL DC_WLOG ( 0, 'FL', iergln, ' ', ierwlg )
	  RETURN
	END IF
	OPEN ( UNIT = iubfma, FILE = '.dummy/dcship',
     +		FORM = 'UNFORMATTED' )
	CALL OPENBF ( iubfma, 'SEC3', iubftn )
	CALL MTINFO ( bufrdn, 98, 99 )
C
C*	Open the messages file for the NCEP BUFR (i.e. output) stream.
C
	CALL FL_GLUN ( iubfmn, iergln )
	IF ( iergln .ne. 0 ) THEN
	  CALL DC_WLOG ( 0, 'FL', iergln, ' ', ierwlg )
	  RETURN
	END IF
C
C*	Connect the tables and messages files for the
C*	NCEP BUFR (i.e. output) stream.
C
	CALL OPENBF ( iubfmn, 'NUL', iubftn )
        r8bfms = GETBMISS()
C
C*      Specify that NCEP BUFR (i.e. output) messages are to be
C*	encoded using edition 4.
C
	CALL PKVS01 ( 'BEN', 4 )
C
C*	Close the tables file for the NCEP BUFR (i.e. output) stream.
C
	CALL FL_CLOS ( iubftn, iercls )
	IF ( iercls .ne. 0 ) THEN
	  CALL DC_WLOG ( 0, 'FL', iercls, ' ', ierwlg )
	END IF
C
	DO WHILE ( .true. )
C
C*	  Get a new bulletin from the input pipe.
C
	  CALL DC_GBUL ( bull, lenb, ifdtyp, iergbl )
	  IF ( iergbl .ne. 0 ) THEN
C
C*	    A time-out occurred while waiting for a new bulletin
C*	    on the input pipe.  Shut down the decoder and exit.
C
	    CALL DC_WLOG ( 0, 'DC', iergbl, ' ', ierwlg )
	    CALL CLOSBF ( iubfma )
	    CALL CLOSBF ( iubfmn )
	    CALL FL_CLAL ( iercal )
	    RETURN
	  END IF
C
	  bullok = .true.
C
C*	  Decode the header information from this bulletin.
C
	  IF ( ifdtyp .eq. 0 ) THEN
C
C*	    Decode WMO products.
C
	    CALL DC_GHDR ( bull, lenb, seqnum, buhd, cborg,
     +			   bulldt, bbb, ibptr, ierghd )
	    IF ( ierghd .ne. 0 ) THEN
	      CALL DC_WLOG ( 2, 'DC', ierghd, ' ', ierwlg )
	      bullok = .false.
	    ELSE
C
C*	      Start an entry for this bulletin in the decoder log.
C
	      logmsg = '########################################'
	      CALL DC_WLOG ( 2, 'DC', 2, logmsg, ierwlg )
	      logmsg = seqnum // buhd // cborg // bulldt // bbb
	      CALL DC_WLOG ( 2, 'DC', 2, logmsg, ierwlg )
	    END IF
	  ELSE
C
C*	    Do not decode AFOS products.
C
	    bullok = .false.
	  END IF
C
	  IF ( bullok ) THEN
C
C*	    Get the system time.
C
	    itype = 1
	    CALL CSS_GTIM ( itype, sysdt, iergtm )
	    IF ( iergtm .ne. 0 ) THEN
	      CALL DC_WLOG ( 2, 'SS', iergtm, ' ', ierwlg )
	      bullok = .false.
	    END IF
	  END IF
C
	  IF ( bullok ) THEN
C
C*	    If a date-time was entered on the command line, then use it
C*	    as the run date-time.  Otherwise, use the system time as
C*	    the run date-time.
C
	    IF ( cldt .eq. 'SYSTEM' ) THEN
	      rundt = sysdt
	    ELSE
	      CALL TI_STAN ( cldt, sysdt, rundt, ierstn )
	      IF ( ierstn .ne. 0 ) THEN
		CALL DC_WLOG ( 2, 'TI', ierstn, ' ', ierwlg )
		bullok = .false.
	      END IF
	    END IF
	  END IF
C
	  IF ( bullok ) THEN
C
C*	    Convert the run date-time to integer.
C
	    CALL TI_CTOI ( rundt, irundt, iercto )
	    IF ( iercto .ne. 0 ) THEN
	      CALL DC_WLOG  ( 2, 'TI', iercto, ' ', ierwlg )
	      bullok = .false.
	    ELSE
	      nmsg = 0
	    END IF
	  END IF
C
	  DO WHILE ( bullok )
C
C*	    Locate the next BUFR message within the bulletin, and
C*	    store it within an equivalenced integer array.
C
	    ipt1 = INDEX ( bull (ibptr:lenb), 'BUFR' )
	    IF ( ipt1 .eq. 0 ) THEN
	      bullok = .false.
	      IF ( nmsg .eq. 0 ) THEN
		IF ( INDEX ( bull (ibptr:lenb), 'NIL' ) .ne. 0 ) THEN
		  logmsg = 'NIL bulletin'
		  CALL DC_WLOG  ( 2, 'DC', 2, logmsg, ierwlg )
		END IF
	      ELSE
C
C*		Make sure that all BUFR output for this bulletin has
C*		been written to the BUFR output stream before going back
C*		to DC_GBUL and waiting for a new bulletin on the pipe.
C
		CALL UT_WBFR ( iubfmn, 'ship', 1, ierwbf )
	      END IF
	    ELSE
	      istart = ibptr + ipt1 - 1
	      ibptr = istart + 4
	      cbull = bull ( istart : lenb )
C
	      nmsg = nmsg + 1
	      msgok = .false.
	      got818 = .false.
C
C*	      Retrieve the Section 3 descriptors from the message to
C*	      ensure it contains WMO SHIP data.
C
	      CALL UPDS3 ( ibull, MXDSC, cdesc, ndesc )
	      ii = 1
	      DO WHILE ( ( ii .le. ndesc ) .and. ( .not. msgok ) )
		IF ( ( cdesc(ii) .eq. '308009' ) .or.
     +		     ( cdesc(ii) .eq. '301093' ) ) THEN
		  msgok = .true.
                ELSE IF ( cdesc(ii) .eq. '308018' ) THEN
		  msgok = .true.
                  got818 = .true.
		ELSE
		  ii = ii + 1
		END IF
	      END DO
C
	      IF ( msgok ) THEN
C
C*		Check if this is a restricted bulletin.
C
		cbb = buhd (1:6) // ' ' // cborg (1:4)
		CALL DC_BSRC  ( cbb, crshpb, nrshpb, ipos, ierbrc )
		IF  ( ipos .ne. 0 )  THEN
		  subtyp = 'NC001101'
		ELSE
		  subtyp = 'NC001113'      
		END IF
C
C*		Open the BUFR message for reading.
C
		CALL READERME ( ibull, iubfma, bfstyp, ibfdt, ierrme )
		IF ( ierrme .ne. 0 ) THEN
		  msgok = .false.
		END IF
	      ELSE
		logmsg = 'message does not follow WMO template:'
		CALL DC_WLOG ( 2, 'DC', 2, logmsg, ierwlg )
		DO ii = 1, ndesc
		  WRITE ( logmsg, FMT = '(I6, A, A)' )
     +		      ii, ': ', cdesc(ii)
		  CALL DC_WLOG ( 2, 'DC', 2, logmsg, ierwlg )
		END DO
	      END IF
C
	      DO WHILE ( msgok )
C
C*		Get the next report from this BUFR message.
C
		IF ( IREADSB ( iubfma ) .ne. 0 ) THEN
C
C*		  There are no more reports in this message.
C
		  msgok = .false.
		ELSE
C
C*		  Get the identification information.
C
		  CALL UFBSEQ ( iubfma, r8in, MXMN, 1, nlv,
     +				'SHPIDENT' )
C
C*		  Don't create BUFR output for reports that are more
C*		  than NHOURS before or more than 3 hours after the
C*		  run time.
C
		  rptyr = UT_BMRI ( r8in (5) )
		  rptmo = UT_BMRI ( r8in (6) )
		  rptdy = UT_BMRI ( r8in (7) )
		  rpthr = UT_BMRI ( r8in (8) )
		  rptmi = UT_BMRI ( r8in (9) )
		  IF ( ( ERMISS ( rptyr ) ) .or.
     +		       ( ERMISS ( rptmo ) ) .or.
     +		       ( ERMISS ( rptdy ) ) .or.
     +		       ( ERMISS ( rpthr ) ) .or.
     +		       ( ERMISS ( rptmi ) ) ) THEN
		    iertmk = -1
		  ELSE
		    irptdt (1) = INT ( rptyr )
		    irptdt (2) = INT ( rptmo )
		    irptdt (3) = INT ( rptdy )
		    irptdt (4) = INT ( rpthr )
		    irptdt (5) = INT ( rptmi )
		    CALL DC_TMCK ( 2, irundt, irptdt, nhours, 180,
     +                             iertmk )
		  END IF
C
		  IF ( iertmk .eq. 0 ) THEN
C
C*                  Open a BUFR message for output.
C
		    ibfdt = ( irptdt (1) * 1000000 )  +
     +			    ( irptdt (2) * 10000 )  +
     +			    ( irptdt (3) * 100 )  +  irptdt (4)
		    CALL OPENMB ( iubfmn, subtyp, ibfdt )
C
C*		    Store the identification information.
C
		    CALL UFBSEQ ( iubfmn, r8in, MXMN, 1, nlv,
     +				  'SHPIDENT' )
C
C*		    Store the report ID.
C
		    CALL READLC ( iubfma, smid, 'SMID' )
		    CALL UT_CIBF ( iubfmn, 'RPID', smid, 8, iercbf )
		    logmsg = subtyp // ':  station ID = ' // smid
		    CALL DC_WLOG  ( 2, 'DC', 2, logmsg, ierwlg )
C
C*		    Get and store the pressure data.
C
		    CALL UFBSEQ ( iubfma, r8in, MXMN, 1, nlv,
     +				  'PRESSQ03' )
		    CALL UFBSEQ ( iubfmn, r8in, MXMN, 1, nlv,
     +				  'PRESSQ03' )
C
C*		    Get and store the instantaneous data.
C
                    IF ( got818 ) THEN
		        CALL UFBSEQ ( iubfma, r8in, MXMN, 1, nlv,
     +				      'TEMHUMDA' )
                        DO ii = 1, 3
                          r8ot (ii) = r8in (ii)
                        END DO
                        r8ot (4) = r8bfms
                        r8ot (5) = r8bfms
                        r8ot (6) = r8in (4)
                        r8ot (7) = r8in (5)
		        CALL UFBSEQ ( iubfmn, r8ot, MXMN, 1, nlv,
     +				      'TEHUDAT2' )
                    ELSE 
		        CALL UFBSEQ ( iubfma, r8in, MXMN, 1, nlv,
     +				      'SHIPINST' )
		        CALL UFBSEQ ( iubfmn, r8in, MXMN, 1, nlv,
     +				      'SHIPINST' )
                    END IF
C
C*		    Get and store the icing data.
C
                    IF ( .not. got818 ) THEN
		        CALL UFBSEQ ( iubfma, r8in, MXMN, 1, nlv,
     +				      'ICINGICE' )
		        CALL UFBSEQ ( iubfmn, r8in, MXMN, 1, nlv,
     +				      'ICINGICE' )
                    END IF
C
C*		    Get and store the marine data.
C
                    IF ( got818 ) THEN
		        CALL UFBSEQ ( iubfma, r8in, MXMN, 1, nlv,
     +				      'SEATEMPM' )
		        CALL UFBSEQ ( iubfmn, r8in, MXMN, 1, nlv,
     +				      'SEATEMPM' )
                    ELSE
		        CALL UFBSEQ ( iubfma, r8in, MXMN, 1, nlv,
     +				      'SHIPDATA' )
		        CALL UFBSEQ ( iubfmn, r8in, MXMN, 1, nlv,
     +				      'SHIPDATA' )
                    END IF
C
C*		    Get and store the period data.
C
                    IF ( got818 ) THEN
		        CALL UFBSEQ ( iubfma, r8in, MXMN, 1, nlv,
     +				      'WINDDATV' )
                        DO ii = 1, 8
                          r8ot (ii) = r8in (ii)
                        END DO
                        DO ii = 9, 14
                          r8ot (ii) = r8bfms
                        END DO
                        CALL GETTAGPR ( iubfma, 'MXGD', 1, tagpr,
     +                                  iertg )
                        IF ( iertg .eq. 0 ) THEN
		          CALL UFBINT ( iubfma, r8gust, 3, 255, nlv,
     +				        tagpr )
                          IF ( nlv .gt. 0 ) THEN
                            r8ot ( 9) = r8gust (1,1)
                            r8ot (10) = r8gust (1,2)
                            r8ot (11) = r8gust (1,3)
                          END IF
                          IF ( nlv .gt. 1 ) THEN
                            r8ot (12) = r8gust (2,1)
                            r8ot (13) = r8gust (2,2)
                            r8ot (14) = r8gust (2,3)
                          END IF
                        END IF
		        CALL UFBSEQ ( iubfmn, r8ot, MXMN, 1, nlv,
     +				      'WINDDAT3' )
                    ELSE
		        CALL UFBSEQ ( iubfma, r8in, MXMN, 1, nlv,
     +				      'SHIPPERD' )
		        CALL UFBSEQ ( iubfmn, r8in, MXMN, 1, nlv,
     +				      'SHIPPERD' )
                    END IF
C
C*                  Get and store the WIGOS identifier.
C*                  Also, write the station ID to the decoder log.
C
                    gotwigos = .false.
                    CALL UFBINT ( iubfma, r8in, MXMN, 1, nlv,
     +                  'WGOSIDS WGOSISID WGOSISNM' )
                    IF ( ( IBFMS ( r8in (1) ) .eq. 0 ) .or.
     +                   ( IBFMS ( r8in (2) ) .eq. 0 ) .or.
     +                   ( IBFMS ( r8in (3) ) .eq. 0 ) ) THEN
                      gotwigos = .true.
                      CALL UFBSEQ ( iubfmn, r8in, MXMN, 1, nlv,
     +                              'WIGOSID' )
                      CALL READLC ( iubfma, wgoslid, 'WGOSLID' )
                    ELSE
                      gotwigos = .false.
                    END IF
C
C*		    Bulletin header.
C
		    CALL UT_CIBF ( iubfmn, 'SEQNUM', seqnum, 8, ier )
		    CALL UT_CIBF ( iubfmn, 'BUHD', buhd, 8, ier )
		    CALL UT_CIBF ( iubfmn, 'BORG', cborg, 8, ier )
		    CALL UT_CIBF ( iubfmn, 'BULTIM', bulldt, 8, ier )
		    CALL UT_CIBF ( iubfmn, 'BBB', bbb, 8, ier )
C
C*		    Receipt time.
C
		    CALL UT_RIBF ( iubfmn, 'RCTS', FLOAT (0), ier )
		    CALL UT_RIBF ( iubfmn, 'RCYR',
     +				   FLOAT ( irundt (1) ), ier )
		    CALL UT_RIBF ( iubfmn, 'RCMO',
     +				   FLOAT ( irundt (2) ), ier )
		    CALL UT_RIBF ( iubfmn, 'RCDY',
     +				   FLOAT ( irundt (3) ), ier )
		    CALL UT_RIBF ( iubfmn, 'RCHR',
     +				   FLOAT ( irundt (4) ), ier )
		    CALL UT_RIBF ( iubfmn, 'RCMI',
     +				   FLOAT ( irundt (5) ), ier )
C
C*		    Correction indicator.
C
		    IF ( ( IUPBS01 ( ibull, 'USN' ) .gt. 0 ) .or.
     +			    ( bbb(1:1) .eq. 'C' ) ) THEN
		      icorn = 1
		    ELSE
		      icorn = 0
		    END IF
		    CALL UT_RIBF ( iubfmn, 'CORN', FLOAT (icorn), ier )
C
		    IF ( subtyp .eq. 'NC001101' ) THEN
C
C*		      Restriction indicator.
C
		      rsrd = PKFTBV(9,1)
		      CALL UT_RIBF ( iubfmn, 'RSRD', rsrd, ierrbf )
		    END IF
C
C*		    Write the BUFR output to the BUFR output stream.
C
		    CALL UT_WBFR ( iubfmn, 'ship', 0, ierwbf )
C
C*                  Write each long string value to the BUFR output
C*                  stream, unless it consists of all blank spaces,
C*                  and in which case just let it default to "missing".
C
                    IF ( gotwigos )
     +                  CALL WRITLC ( iubfmn, wgoslid, 'WGOSLID' )
		  END IF
		END IF
	      END DO
            END IF
	  END DO
	END DO
C*
	RETURN
	END