SUBROUTINE GP_IFSP  ( rimnem, cimnem, iret )
C************************************************************************
C* GP_IFSP								*
C*									*
C* This subroutine initializes the interface mnemonic arrays and sets	*
C* the pointers within COMMON / RINTFP / and COMMON / CINTFP /.		*
C*									*
C* GP_IFSP  ( RIMNEM, CIMNEM, IRET )					*
C*									*
C* Output parameters:							*
C*	RIMNEM (*)	CHAR*		Interface mnemonics for reals	*
C*	CIMNEM (*)	CHAR*		Interface mnemonics for chars	*
C*	IRET		INTEGER		Return code 			*
C*					  0 = normal return 		*
C*					 -1 = one or more pointers	*
C*					      could not be set 		*
C*									*
C**									*
C* Log:									*
C* J. Ator/NCEP		01/98						*
C* J. Ator/NCEP		01/99	Added intf mnemonics to calling sequence*
C* J. Ator/NCEP		01/00	Clean up function declarations		*
C* R. Hollern/NCEP	05/00	Initialized multi-level data            *
C* J. Ator/NCEP		09/00	Removed "GEMINC:" prefix from INCLUDEs	*
C* C. Caruso Magee/NCEP 03/01   Modifying for dcgpsw.                   * 
C************************************************************************
	INCLUDE		'GEMPRM.PRM'
	INCLUDE		'gpcmn.cmn'
C*
	CHARACTER*(*)	rimnem (*), cimnem (*)
C*
	LOGICAL		allok
	INTEGER		iploc ( NRIMN )
	CHARACTER	rifmn ( NRIMN )*8, cifmn ( NCIMN )*8
C*
C*	Establish equivalance between iploc ( ) and COMMON / RINTFP /
C*
	EQUIVALENCE	( iploc (1), iryear )
C*
C*	Real interface mnemonics.
C*
	DATA	( rifmn (i), i = 1, NRIMN )
     +	/  'YEAR'  , 'MNTH'  , 'DAYS'  , 'HOUR'  , 'MINU'  , 
     +	   'SLAT'  , 'SLON'  , 'SELV'  , 'PRES'  , 'TMPK'  ,
     +	   'RELH'  , 'TDEL'  , 'ETDL'  , 'HSDL'  , 'EHSD'  ,
     +	   'TPWT'  , 'WMTM'  , 'WDMF'  / 
C*
C*      Character interface mnemonics.
C*
	DATA	( cifmn (i), i = 1, NCIMN ) 
     +	/  'GPID'  /
C-----------------------------------------------------------------------
	iret = 0
C
C*	Initialize the interface mnemonics.
C
	DO i = 1, NRIMN
	    rimnem ( i ) = rifmn ( i ) 
	END DO
	DO i = 1, NCIMN
	    cimnem ( i ) = cifmn ( i )
	END DO
C
C*	The logical variable "allok" is initially set to .true. but will
C*	be reset to .false. if any of the pointers cannot be set.
C
	allok = .true.
C
C*	Set the pointers for the real interface mnemonics.
C
	DO ii = 1, NRIMN
	    CALL DC_IFFP  ( rimnem (ii), rimnem, NRIMN, allok,
     +			    iploc (ii), ier ) 
	END DO
C
C*	Set the pointers for the character interface mnemonics.
C
	CALL DC_IFFP  ( 'GPID', cimnem, NCIMN, allok, icgpid, ier )
C
C*	Were all of the pointers properly set?
C
	IF  ( .not. allok ) THEN
	    iret = -1
	END IF
C*
	RETURN
	END