SUBROUTINE EP_IFPT  ( loglev, r8mnem, rimnem, iret )
C************************************************************************
C* EP_IFPT								*
C*									*
C* This subroutine prints the interface values arrays to the decoder	*
C* log if the verbosity level is LOGLEV or higher.			*
C*									*
C* EP_IFPT  ( LOGLEV, R8MNEM, RIMNEM, IRET )				*
C*									*
C* Input parameters:							*
C*      LOGLEV          INTEGER         Verbosity level                 *
C*	R8MNEM(*)	CHAR*		Real*8 interface mnemonics	*
C*	RIMNEM(*)	CHAR*		Real interface mnemonics	*
C*									*
C* Output parameters:							*
C*	IRET		INTEGER		Return code 			*
C*					  0 = normal return 		*
C*									*
C**									*
C* Log:									*
C* J. Ator/NCEP		03/06						*
C* J. Ator/NCEP		03/09	Use IBFMS instead of UT_BFMS		*
C************************************************************************
	INCLUDE		'GEMPRM.PRM'
	INCLUDE		'epcmn.cmn'
C*
        CHARACTER*(*)    r8mnem (*), rimnem (*)
C*
C*	Format statement
C*
  333	FORMAT (F6.0,2X,F4.0,2X,F5.0,1X,F5.1,2X,F4.0,1X,F6.2,1X,F5.0)
C-----------------------------------------------------------------------
	iret = 0
C
C*	Single-level data.
C
	DO ii = 1, NR8IMN
	    IF  ( IBFMS ( r8vals ( ii ) ) .eq. 0 )  THEN
		WRITE  ( UNIT = logmsg, FMT = '( A6, A, G12.4 )' )
     +		    r8mnem ( ii ), '= ', r8vals ( ii )
		CALL DC_WLOG  ( loglev, 'DC', 2, logmsg, ierwlg )
	    END IF
	END DO
C
	CALL DC_IFPR  ( loglev, rimnem, rivals, NRSIMN, ierfpr )
C
C*	Multi-level data.
C
	WRITE ( UNIT = logmsg, FMT = '( 1X, A5 )' )  rimnem ( irnlev )
	CALL DC_WLOG  ( loglev, 'DC', 2, logmsg, ierwlg )
	WRITE ( UNIT = logmsg, FMT = '( F6.0 )')  rivals ( irnlev )
	CALL DC_WLOG  ( loglev, 'DC', 2, logmsg, ierwlg )
C
	nlev = INT ( rivals ( irnlev ) )
	IF  ( nlev .gt. 0 )  THEN
	    WRITE ( UNIT = logmsg,
     +		    FMT = '( 2(1X, A6), 1X, 3A6, 1X, 2A6 )' )
     +		rimnem ( irhgtm (1) ), rimnem ( irqmdr (1) ),
     +		rimnem ( irdrct (1) ), rimnem ( irsped (1) ),
     +		rimnem ( irqmwc (1) ), rimnem ( irwcmp (1) ),
     +		rimnem ( irstnr (1) )
	    CALL DC_WLOG  ( loglev, 'DC', 2, logmsg, ierwlg )
	    DO jj = 1, nlev
		WRITE ( UNIT = logmsg, FMT = 333 )
     +		rivals ( irhgtm (jj) ), rivals ( irqmdr (jj) ),
     +		rivals ( irdrct (jj) ), rivals ( irsped (jj) ),
     +		rivals ( irqmwc (jj) ), rivals ( irwcmp (jj) ),
     +		rivals ( irstnr (jj) )
	        CALL DC_WLOG  ( loglev, 'DC', 2, logmsg, ierwlg )
	    END DO
	END IF
C*
	RETURN
	END