SUBROUTINE CP_IFPT  ( loglev, rimnem, cimnem, iret )
C************************************************************************
C* CP_IFPT								*
C*									*
C* This subroutine prints the interface values arrays to the decoder	*
C* log if the verbosity level is LOGLEV or higher.			*
C*									*
C* CP_IFPT  ( LOGLEV, RIMNEM, CIMNEM, IRET )				*
C*									*
C* Input parameters:							*
C*	LOGLEV		INTEGER		Verbosity level			*
C*	RIMNEM (*)	CHAR*		Interface mnemonics for reals   *
C*	CIMNEM (*)	CHAR*		Interface mnemonics for chars   *
C*									*
C* Output parameters:							*
C*	IRET		INTEGER		Return code 			*
C*					  0 = normal return 		*
C*									*
C**									*
C* Log:									*
C* J. Ator/NCEP		07/06						*
C************************************************************************
	INCLUDE		'GEMPRM.PRM'
	INCLUDE		'cpcmn.cmn'
C*
	CHARACTER*(*)	rimnem (*), cimnem (*)
C-----------------------------------------------------------------------
	iret = 0
C
	ncsl = ( ictmpkqd - 1 )
	CALL DC_IFPC  ( loglev, cimnem, civals, ncsl, ierfpc )
C
	nrsl = ( irtmpk - 1 )
	CALL DC_IFPR  ( loglev, rimnem, rivals, nrsl, ierfpr )
C
	CALL CP_IFPQ  ( loglev, rimnem, cimnem,
     +			irtmpk, ictmpkqd, irtmpkqa, irtmpkqr, ierfpq )
	CALL CP_IFPQ  ( loglev, rimnem, cimnem,
     +			irdwpk, icdwpkqd, irdwpkqa, irdwpkqr, ierfpq )
	CALL CP_IFPQ  ( loglev, rimnem, cimnem,
     +			irdrct, icdrctqd, irdrctqa, irdrctqr, ierfpq )
	CALL CP_IFPQ  ( loglev, rimnem, cimnem,
     +			irsped, icspedqd, irspedqa, irspedqr, ierfpq )
	CALL CP_IFPQ  ( loglev, rimnem, cimnem,
     +			irpc1h, icpc1hqd, irpc1hqa, irpc1hqr, ierfpq )
	CALL CP_IFPQ  ( loglev, rimnem, cimnem,
     +			irtosd, ictosdqd, irtosdqa, irtosdqr, ierfpq )
C
	IF  ( rivals ( irnsol ) .gt. 0 )  THEN
	    WRITE ( UNIT = logmsg, FMT = '( 10A9 )' )
     +		rimnem ( irnsol ),       rimnem ( irslin (1) ),
     +		rimnem ( irsolm (1) ),   cimnem ( icsolmqd (1) ),
     +		rimnem ( irsolmqa (1) ), rimnem ( irsolmqr (1) ),
     +		rimnem ( irsolt (1) ),   cimnem ( icsoltqd (1) ),
     +		rimnem ( irsoltqa (1) ), rimnem ( irsoltqr (1) )
	    CALL DC_WLOG  ( loglev, 'DC', 2, logmsg, ierwlg )
	    WRITE ( UNIT = logmsg,
     +		    FMT = '( 2F9.2, 2(F9.2, 4X, A5, 2F9.2 ))' )
     +		rivals ( irnsol ),       rivals ( irslin (1) ),
     +		rivals ( irsolm (1) ),   civals ( icsolmqd (1) ),
     +		rivals ( irsolmqa (1) ), rivals ( irsolmqr (1) ),
     +		rivals ( irsolt (1) ),   civals ( icsoltqd (1) ),
     +		rivals ( irsoltqa (1) ), rivals ( irsoltqr (1) )
	    CALL DC_WLOG  ( loglev, 'DC', 2, logmsg, ierwlg )
C
	    IF  ( rivals ( irnsol ) .gt. 1 )  THEN
		DO jj = 2, INT ( rivals ( irnsol ) )
		    WRITE ( UNIT = logmsg,
     +			FMT = '( 9X, F9.2, 2(F9.2, 4X, A5, 2F9.2 ))' )
     +		    rivals ( irslin (jj) ),
     +		    rivals ( irsolm (jj) ),   civals ( icsolmqd (jj) ),
     +		    rivals ( irsolmqa (jj) ), rivals ( irsolmqr (jj) ),
     +		    rivals ( irsolt (jj) ),   civals ( icsoltqd (jj) ),
     +		    rivals ( irsoltqa (jj) ), rivals ( irsoltqr (jj) )
	    	    CALL DC_WLOG  ( loglev, 'DC', 2, logmsg, ierwlg )
		END DO
	    END IF
	END IF
C
	IF  ( rivals ( irnsnw ) .gt. 0 )  THEN
	    WRITE ( UNIT = logmsg, FMT = '( 6A9 )' )
     +		rimnem ( irnsnw ),       rimnem ( irsnhr (1) ),
     +		rimnem ( irdofs (1) ),   cimnem ( icdofsqd (1) ),
     +		rimnem ( irdofsqa (1) ), rimnem ( irdofsqr (1) )
	    CALL DC_WLOG  ( loglev, 'DC', 2, logmsg, ierwlg )
	    WRITE ( UNIT = logmsg,
     +		    FMT = '( 3F9.2, 4X, A5, 2F9.2 )' )
     +		rivals ( irnsnw ),       rivals ( irsnhr (1) ),
     +		rivals ( irdofs (1) ),   civals ( icdofsqd (1) ),
     +		rivals ( irdofsqa (1) ), rivals ( irdofsqr (1) )
	    CALL DC_WLOG  ( loglev, 'DC', 2, logmsg, ierwlg )
C
	    IF  ( rivals ( irnsnw ) .gt. 1 )  THEN
		DO jj = 2, INT ( rivals ( irnsnw ) )
		    WRITE ( UNIT = logmsg,
     +			    FMT = '( 9X, 2F9.2, 4X, A5, 2F9.2 )' )
     +		    rivals ( irsnhr (jj) ),
     +		    rivals ( irdofs (jj) ),   civals ( icdofsqd (jj) ),
     +		    rivals ( irdofsqa (jj) ), rivals ( irdofsqr (jj) )
	    	    CALL DC_WLOG  ( loglev, 'DC', 2, logmsg, ierwlg )
		END DO
	    END IF
	END IF
C*
	RETURN
	END