SUBROUTINE  BT_INST ( report, ip, iret )
C************************************************************************
C* BT_INST                                                              *
C*                                                                      *
C* This subroutine decodes the group containing the instrument type for *
C* water temperature profile measurements with fall rate equation       *
C* coefficients and the water temperature profile recorder type.        *
C*                                                                      *
C* BT_INST ( REPORT, IP, IRET )                                         *
C*                                                                      *
C* Input parameters:                                                    *
C*                                                                      *
C*      REPORT          CHAR*           Report array                    *
C*					                                *
C* Input and Output Parameters:                                         *
C*      IP             INTEGER           Pointer to position of         *
C*                                       characters in report           *
C*					                                *
C* Output parameters:                                                   *
C*                                                                      *
C*      RIVALS(IRIWTM)  REAL            Instrument for water temp meas  *
C*      RIVALS(IRWTMR)  REAL            Water temperature recorder type *
C*      IRET            INTEGER         Return code                     *
C*                                         0 = Normal return            *
C*                                         1 = No section 2 data        *
C*                                                                      *
C**                                                                     *
C* Log:                                                                 *
C* R. Hollern/NCEP       4/00                                           *
C************************************************************************
        INCLUDE         'btcmn.cmn'
C*
        CHARACTER*(*)   report
C*
        CHARACTER       fld2*2,  fld3*3
C------------------------------------------------------------------------
        iret  = 0
C
C*      Get the instrument type for water temperature profile
C*      measurement.
C
        fld3 = report ( ip:ip+2 )
C*
        CALL  ST_INTG ( fld3, ival, ier )
        IF ( ier .eq. 0 ) THEN
            rivals ( iriwtm ) = FLOAT ( ival )
          ELSE
            iret = 1 
            RETURN
        END IF
C
        ip = ip + 3
C
C*      Get the water temperature profile recorder type.
C
        fld2 = report ( ip:ip+1 )
C 
        CALL  ST_INTG ( fld2, ival, ier )
        IF ( ier .eq. 0 ) THEN
            rivals ( irwtmr ) = FLOAT ( ival )
          ELSE
            iret = 1 
            RETURN
        END IF
C*
	RETURN
	END