SUBROUTINE GETLALO(RLATS,RLONS,WGTS,JCAP,NLON,NLATH,
     *    DEL2OUT,TRIGS,IFAX,PLN,QLN,RLN)
C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    GETLALO    RETURN GAUSSIAN LATS AND LONS AND TRANCONS
C   PRGMMR: PARRISH          ORG: W/NMC22    DATE: 90-09-21
C
C ABSTRACT: RETURN GAUSSIAN LATS, LONS, AND TRANSFORM STUFF.
C
C PROGRAM HISTORY LOG:
C   90-09-21  PARRISH
C
C   INPUT ARGUMENT LIST:
C     JCAP     - TRIANGULAR TRUNCATION
C     NLON     - NUMBER OF LONGITUDES
C     NLATH    - NUMBER OF GAUSSIAN LATS IN ONE HEMISPHERE
C
C   OUTPUT ARGUMENT LIST:
C     RLATS,RLONS    - GRID LATITUDES, LONGITUDES (RADIANS)
C     WGTS     - GAUSSIAN INTEGRATION WEIGHTS
C     PLN,QLN,RLN - SPHERICAL HARMONICS.
C     DEL2     - N*(N+1)/(A**2)
C     TRIGS,IFAX - USED BY FFT
C
C ATTRIBUTES:
C   LANGUAGE: CFT77
C   MACHINE:  CRAY YMP
C
C$$$
C
C-CRA          DIMENSION RLATS(2*NLATH),WGTS(2*NLATH),RLONS(NLON)
C-CRA          DIMENSION AP(0:JCAP,0:JCAP),BP(0:JCAP,0:JCAP)
C-CRA          DIMENSION AQR(0:JCAP,0:JCAP),BQR(0:JCAP,0:JCAP)
C-CRA          DIMENSION GR(0:JCAP,0:JCAP),DEL2(0:JCAP,0:JCAP)
C-CRA          DIMENSION SLAT(NLATH),CLAT(NLATH),TRIGS(NLON*2),IFAX(10)
C-CRA          DIMENSION PE0(NLATH,0:JCAP),QE0(NLATH,0:JCAP),RO0(NLATH,0:JCAP)
C-CRA          DIMENSION PLN((JCAP+1)*(JCAP+2),NLATH)
C-CRA          DIMENSION QLN((JCAP+1)*(JCAP+2),NLATH)
C-CRA          DIMENSION RLN((JCAP+1)*(JCAP+2),NLATH)
C-CRA          DIMENSION DEL2OUT((JCAP+1)*(JCAP+2))
C-CRA          DIMENSION W1(NLATH-1),W2(NLATH-1),W3(NLATH-1),W4(NLATH-1)
 
          DIMENSION RLATS(2*48),WGTS(2*48),RLONS(192)
          DIMENSION AP(0:62,0:62),BP(0:62,0:62)
          DIMENSION AQR(0:62,0:62),BQR(0:62,0:62)
          DIMENSION GR(0:62,0:62),DEL2(0:62,0:62)
          DIMENSION SLAT(48),CLAT(48),TRIGS(192*2),IFAX(10)
          DIMENSION PE0(48,0:62),QE0(48,0:62)
          DIMENSION RO0(48,0:62)
          DIMENSION PLN((62+1)*(62+2),48)
          DIMENSION QLN((62+1)*(62+2),48)
          DIMENSION RLN((62+1)*(62+2),48)
          DIMENSION DEL2OUT((62+1)*(62+2))
          DIMENSION W1(48-1),W2(48-1),W3(48-1),W4(48-1)
C--------
C--------
C-------- GET STUFF FOR FFT*S
C-------
C-CRA             CALL FFTFAX(NLON,IFAX,TRIGS)
             CALL FAX   (IFAX,NLON,3)
             CALL FFTRIG(TRIGS,NLON,3)

C--------
C-------- COMPUTE RECURSION CONSTANTS AND INITIALIZE LEGENDRE FUNCTIONS
C--------
      CALL M1RCONS(AP,BP,AQR,BQR,GR,DEL2,JCAP)
C--------
C-------- GET LATITUDES, LONGITUDES, AND INTEGRATION WEIGHTS.
C-------
      PIH=2.*ATAN(1.)
      CALL M1GLAT(NLATH-1,W1,W2,W3,W4)
      RLATS(1)=-PIH
      WGTS(1)=0.
      DO 100 I=1,NLATH-1
        RLATS(I+1)=W1(I)-PIH
        WGTS(I+1)=W2(I)
100   CONTINUE
      DO 200 I=1,NLATH
        RLATS(NLATH*2+1-I)=-RLATS(I)
        WGTS(NLATH*2+1-I)=WGTS(I)
        SLAT(I)=SIN(RLATS(I))
        CLAT(I)=COS(RLATS(I))
200   CONTINUE
      DLON=8.*ATAN(1.)/NLON
      DO 300 I=1,NLON
        RLONS(I)=(I-1.)*DLON
300   CONTINUE
C--------
C-------- NEXT GET INITIAL P,Q,R.
C--------
      CALL M1IPQR(PE0,QE0,RO0,SLAT,CLAT,NLATH,JCAP)
C-------- FINALLY GET PLN,QLN,RLN
      CALL GETPLN(PLN,QLN,RLN,JCAP,NLATH,AP,BP,SLAT,PE0,
     *          QE0,RO0,AQR,BQR,GR,CLAT,DEL2,DEL2OUT)
      RETURN
      END